Home · All Classes · All Functions · Overviews

Data Models

Some QML Items use Data Models to provide the data to be displayed. These items typically require a delegate component that creates an instance for each item in the model. Models may be static, or have items modified, inserted, removed or moved dynamically.

Data is provided to the delegate via named data roles which the delegate may bind to. The roles are exposed as properties of the model context property, though this property is set as a default property of the delegate so, unless there is a naming clash with a property in the delegate, the roles are usually accessed unqualified. The example below would have a clash between he color role of the model and the color property of the Rectangle. The clash is avoided by referencing the color property of the model by its full name: model.color.

 ListModel {
     id: myModel
     ListElement { color: "red" }
     ListElement { color: "green" }
 }

 Component {
     id: myDelegate
     Rectangle {
         width: 20; height: 20
         color: model.color
     }
 }

A special index role containing the index of the item in the model is also available.

Note: the index role will be set to -1 if the item is removed from the model. If you bind to the index role, be sure that the logic accounts for the possibility of index being -1, i.e. that the item is no longer valid. Usually the item will shortly be destroyed, but it is possible to delay delegate destruction in some views via a delayRemove attached property.

Models that do not have named roles will have the data provided via the modelData role. The modelData role is also provided for Models that have only one role. In this case the modelData role contains the same data as the named role.

There are a number of QML elements that operate using data models:

QML supports several types of data model, which may be provided by QML or C++ (via QDeclarativeContext::setContextProperty(), for example).

QML Data Models

ListModel

ListModel is a simple hierarchy of elements specified in QML. The available roles are specified by the ListElement properties.

 ListModel {
     id: fruitModel
     ListElement {
         name: "Apple"
         cost: 2.45
     }
     ListElement {
         name: "Orange"
         cost: 3.25
     }
     ListElement {
         name: "Banana"
         cost: 1.95
     }
 }

The above model has two roles, name and cost. These can be bound to by a ListView delegate, for example:

 Component {
     id: fruitDelegate
     Row {
         Text { text: "Fruit: " + name }
         Text { text: "Cost: $" + cost }
     }
 }
 ListView {
     model: fruitModel
     delegate: fruitDelegate
 }

XmlListModel

XmlListModel allows construction of a model from an XML data source. The roles are specified via the XmlRole element.

The following model has three roles, title, link and description:

 XmlListModel {
      id: feedModel
      source: "http://rss.news.yahoo.com/rss/oceania"
      query: "/rss/channel/item"
      XmlRole { name: "title"; query: "title/string()" }
      XmlRole { name: "link"; query: "link/string()" }
      XmlRole { name: "description"; query: "description/string()" }
 }

VisualItemModel

VisualItemModel allows QML items to be provided as a model. This model contains both the data and delegate (its child items). This model does not provide any roles.

  VisualItemModel {
      id: itemModel
      Rectangle { height: 30; width: 80; color: "red" }
      Rectangle { height: 30; width: 80; color: "green" }
      Rectangle { height: 30; width: 80; color: "blue" }
  }

  ListView {
      anchors.fill: parent
      model: itemModel
  }

Note that in the above example there is no delegate required. The items of the model itself provide the visual elements that will be positioned by the view.

C++ Data Models

QAbstractItemModel

QAbstractItemModel provides the roles set via the QAbstractItemModel::setRoleNames() method.

QStringList

QStringList provides the contents of the list via the modelData role:

 // main.cpp
 QStringList dataList;
 dataList.append("Fred");
 dataList.append("Ginger");
 dataList.appenf("Skipper");

 QDeclarativeContext *ctxt = view.rootContext();
 ctxt->setContextProperty("myModel", QVariant::fromValue(&dataList));
 // main.qml
 ListView {
    width: 100
    height: 100
    anchors.fill: parent
    model: myModel
    delegate: Component {
        Rectangle {
             height: 25
             Text { text: modelData }
        }
    }
 }

Note: There is no way for the view to know that the contents of a QStringList have changed. If the QStringList is changed, it will be necessary to reset the model by calling QDeclarativeContext::setContextProperty() again.

QList<QObject*>

QList<QObject*> provides the properties of the objects in the list as roles.

 class DataObject : public QObject
 {
     Q_OBJECT

     Q_PROPERTY(QString name READ name WRITE setName)
     Q_PROPERTY(QString color READ color WRITE setColor)
 ...
 };

 QList<QObject*> dataList;
 dataList.append(new DataObject("Item 1", "red"));
 dataList.append(new DataObject("Item 2", "green"));
 dataList.append(new DataObject("Item 3", "blue"));
 dataList.append(new DataObject("Item 4", "yellow"));

 QDeclarativeContext *ctxt = view.rootContext();
 ctxt->setContextProperty("myModel", QVariant::fromValue(dataList));

The properties of the object may then be accessed in the delegate:

 ListView {
    width: 100
    height: 100
    anchors.fill: parent
    model: myModel
    delegate: Component {
        Rectangle {
             height: 25
             width: 100
             color: model.color
             Text { text: name }
        }
    }
 }

Note: There is no way for the view to know that the contents of a QList have changed. If the QList is changed, it will be necessary to reset the model by calling QDeclarativeContext::setContextProperty() again.

Other Data Models

An Integer

An Integer specifies a model containing the integer number of elements. There are no data roles.

The following example creates a ListView with five elements:

 Component {
     id: itemDelegate
     Text { text: "I am item number: " + index }
 }
 ListView {
     model: 5
     delegate: itemDelegate
 }

An Object Instance

An Object Instance specifies a model with a single Object element. The properties of the object are provided as roles.

The example below creates a list with one item, showing the color of the myText text. Note the use of the fully qualified model.color property to avoid clashing with color property of the Text element in the delegate.

 Rectangle {
     Text {
         id: myText
         text: "Hello"
         color: "#dd44ee"
     }

     Component {
         id: myDelegate
         Text {
             text: model.color
         }
     }
     ListView {
         anchors.fill: parent
         anchors.topMargin: 30
         model: myText
         delegate: myDelegate
     }
 }


Copyright © 2010 Nokia Corporation and/or its subsidiary(-ies) Trademarks
Qt 4.7.0